Función ELEGIR De Excel. Fórmulas Y Ejemplos

El tutorial explica la sintaxis y los usos básicos de la función ELEGIR de Excel y proporciona algunos ejemplos no triviales que muestran cómo usar una fórmula ELEGIR. Se trata de una de esas funciones de Excel que pueden no parecer útiles por sí solas, pero combinadas con otras funciones brindan una serie de increíbles beneficios. En el nivel más básico, se usa la función ELEGIR para obtener un valor de una lista especificando la posición de ese valor. Más adelante en este tutorial, encontrará varios usos avanzados que sin duda vale la pena explorar.

Índice De Contenidos

    Función ELEGIR de Excel: sintaxis y usos básicos

    La función ELEGIR en Excel está diseñada para devolver un valor de la lista en función de una posición específica. La función está disponible en Excel 365, Excel 2019, Excel 2016, Excel 2013, Excel 2010 y Excel 2007.

    La sintaxis de la función ELEGIR es la siguiente:

    ELEGIR (Index_num, valor1, [valor2],…)

    Dónde:

    Index_num (obligatorio): la posición del valor que se devolverá. Puede ser cualquier número entre 1 y 254, una referencia de celda u otra fórmula.

    Valor1, valor2,…: una lista de hasta 254 valores entre los que elegir. Valor1 es obligatorio, otros valores son opcionales. Estos pueden ser números, valores de texto, referencias de celda, fórmulas o nombres definidos. Aquí hay un ejemplo de una fórmula ELEGIR en la forma más simple:

    =CHOOSE(3, "Mike", "Sally", "Amy", "Neal")

    La fórmula devuelve "amy" porque Index_num es 3 y "Amy" es el tercer valor de la lista:

    Función ELEGIR de Excel

    Quizás te puede interesar: Cómo Utilizar Las Funciones Izquierda Y Derecha En Excel

    Función ELEGIR de Excel: ¡3 cosas para recordar!

    ELEGIR es una función muy sencilla y difícilmente encontrarás dificultades para implementarla en tus hojas de trabajo. Si el resultado devuelto por tu fórmula ELEGIDA es inesperado o no es el resultado que estabas buscando, puede deberse a las siguientes razones:

    1. El número de valores para elegir está limitado a 254.
    2. Se devuelve el error.
    3. Si el argumento Index_num es una fracción, se trunca al número entero más bajo.

    Cómo usar la función ELEGIR en Excel - ejemplos de fórmulas

    Los siguientes ejemplos muestran cómo CHOOSE puede ampliar las capacidades de otras funciones de Excel y proporcionar soluciones alternativas a algunas tareas comunes, incluso a aquellas que muchos consideran inviables.

    ELEGIR en Excel en lugar de IF anidada

    Una de las tareas más frecuentes en Excel es devolver diferentes valores según una condición específica. En la mayoría de los casos, esto se puede hacer utilizando una instrucción IF anidada clásica. Pero la función ELEGIR de Excel puede ser una alternativa rápida y fácil de entender.

    Ejemplo 1: Devuelve diferentes valores según la condición

    Supongamos que tienes una columna de calificaciones de los estudiantes y deseas etiquetar las calificaciones en función de las siguientes condiciones: Resultado y puntaje.

    • Pobre: 0 - 50
    • Satisfactorio: 51 - 100
    • Bueno: 101 - 150
    • Excelente: más de 151

    Una forma de hacer esto es anidar algunas fórmulas IF unas dentro de otras:

    =IF(B2>=151, "Excelente", IF(B2>=101, "Bueno", IF(B2>=51, "Satisfactorio", "Pobre")))

    Otra forma es elegir una etiqueta que corresponda a la condición:

    =CHOOSE((B2>0) + (B2>=51) + (B2>=101) + (B2>=151), "Pobre", "Satisfactorio", "Bueno", "Excelente")

    Función ELEGIR de Excel

    Cómo funciona esta fórmula:

    Lee También:   Como se Hace la Marca de Verificación en Excel ✔

    En el argumento Index_num, evalúa cada condición y devuelve VERDADERO si se cumple la condición, FALSO en caso contrario. Por ejemplo, el valor en la celda B2 cumple con las tres primeras condiciones, por lo que obtenemos este resultado intermedio:

    =CHOOSE(TRUE + TRUE + TRUE + FALSE, "Pobre", "Satisfactorio", "Bueno", "Excelente")

    Dado que en la mayoría de las fórmulas de Excel, VERDADERO equivale a 1 y FALSO a 0, nuestra fórmula sufre esta transformación:

    =CHOOSE(1 + 1 + 1 + 0, "Pobre", "Satisfactorio", "Bueno", "Excelente")

    Una vez realizada la operación de suma, tenemos:

    =CHOOSE(3, "Pobre", "Satisfactorio", "Bueno", "Excelente")

    Como resultado, el 3 rd valor en la lista se devuelve, el cual es "bueno".

    Consejos:

    • Para hacer que la fórmula sea más flexible, puedes usar referencias de celda en lugar de etiquetas codificadas, por ejemplo:

    =CHOOSE((B2>0) + (B2>=51) + (B2>=101) + (B2>=151), $E$1, $E$2, $E$3, $E$4)

    • Si ninguna de tus condiciones es VERDADERA, el argumento Index_num se establecerá en 0, lo que obligará a tu fórmula a devolver el # ¡VALOR! error. Para evitar esto, simplemente envuelve CHOOSE en la función IFERROR de esta manera:

    =IFERROR(CHOOSE((B2>0) + (B2>=51) + (B2>=101) + (B2>=151), "Pobre", "Satisfactorio", "Bueno", "Excelente"), "")

    Ejemplo 2: Realiza diferentes cálculos según la condición

    Puedes usar la función ELEGIR de Excel para realizar un cálculo en una serie de posibles cálculos / fórmulas sin anidar múltiples declaraciones IF entre sí. Como ejemplo, calculemos la comisión de cada vendedor en función de sus ventas:

    • 5% - 0$ a 50$
    • 7% - 51$ a 100$
    • 10% - más de 101$

    Con el monto de las ventas en B2, la fórmula toma la siguiente forma:

    =CHOOSE((B2>0) + (B2>=51) + (B2>=101), B2*5%, B2*7%, B2*10%)

    Función ELEGIR de Excel

    En lugar de codificar los porcentajes en la fórmula, puedes consultar la celda correspondiente en tu tabla de referencia, si hay alguna. Solo recuerda arreglar las referencias usando el signo $.

    =CHOOSE((B2>0) + (B2>=51) + (B2>=101), B2*$E$2, B2*$E$3, B2*$E$4)

     La fórmula Elegir para generar datos aleatorios

    Como probablemente sepas, Microsoft Excel tiene una función especial para generar números enteros aleatorios entre los números inferiores y superiores que especifiques: función RANDBETWEEN. Usa el argumento index_num de CHOOSE, y tu fórmula generará casi cualquier dato aleatorio que desees. Por ejemplo, esta fórmula puede producir una lista de resultados de exámenes aleatorios:

    =CHOOSE(RANDBETWEEN(1,4), "Pobre", "Satisfactorio", "Bueno", "Excelente")

    Fórmula Elegir en Excel

    La lógica de la fórmula es obvia: RANDBETWEEN genera números aleatorios del 1 al 4 y ELEGIR devuelve un valor correspondiente de la lista predefinida de cuatro valores.

    Nota: RANDBETWEEN es una función volátil y se recalcula con cada cambio que realiza en la hoja de trabajo. Como resultado, tu lista de valores aleatorios también cambiará. Para evitar que esto suceda, puedes reemplazar fórmulas con tus valores utilizando la función Pegado especial.

    Tal vez quieras saber: Cómo Vincular Una Lista Desplegable En Excel

    La fórmula Elegir para hacer un Vlookup izquierdo

    Si alguna vez ha realizado una búsqueda vertical en Excel, sabes que la función VLOOKUP solo puede buscar en la columna más a la izquierda. En situaciones en las que necesitas devolver un valor a la izquierda de la columna de búsqueda, puedes usar la combinación INDICE / COINCIDIR o engañar a BUSCARV anidando la función ELEGIR en ella. Así es cómo:

    Supongamos que tienes una lista de puntuaciones en la columna A, los nombres de los estudiantes en la columna B y deseas recuperar la puntuación de un estudiante en particular. Dado que la columna de retorno está a la izquierda de la columna de búsqueda, una fórmula de Vlookup normal devuelve el error # N / A:

    Lee También:   Cómo Crear un Índice En Excel Automáticamente

    Fórmula Elegir en Excel

    Para solucionar esto, obtén la función ELEGIR para intercambiar las posiciones de las columnas, indicándole a Excel que la columna 1 es B y la columna 2 es A:

    =CHOOSE({1,2}, B2:B5, A2:A5)

    Debido a que proporcionamos una matriz de {1,2} en el argumento núm_índice, la función ELEGIR acepta rangos en el valor argumentos de (normalmente, no lo hace). Ahora, incrusta la fórmula anterior en el argumento table_array de BUSCARV:

    =VLOOKUP(E1,CHOOSE({1,2}, B2:B5, A2:A5),2,FALSE)

    Con esto ¡se realiza una búsqueda a la izquierda sin problemas!

    Fórmula Elegir en Excel

    La fórmula Elegir para devolver el próximo día laborable

    Si no estás seguro de si debes ir a trabajar mañana o puedes quedarte en casa y disfrutar de tu merecido fin de semana, la función ELEGIR de Excel puede averiguar cuándo es el próximo día laboral. Suponiendo que tus días laborables son de lunes a viernes, la fórmula es la siguiente:

    =TODAY()+CHOOSE(WEEKDAY(TODAY()),1,1,1,1,1,3,2)

    Fórmula Elegir en Excel

    Difícil a primera vista, al mirar más de cerca la lógica de la fórmula es fácil de seguir:

    WEEKDAY (TODAY ()) devuelve un número de serie correspondiente a la fecha de hoy, que va de 1 (domingo) a 7 (sábado). Este número va al argumento Index_num de nuestra fórmula ELEGIR.

    Valor1 - valor7 (1,1,1,1,1,3,2) determina cuántos días agregar a la fecha actual. Si hoy es domingo - jueves (index_num 1 - 5), agrega 1 para devolver el día siguiente. Si hoy es viernes (index_num 6), agrega 3 para regresar el próximo lunes. Si hoy es sábado (index_num 7), agrega 2 para regresar el próximo lunes nuevamente. Sí, es así de simple.

    Fórmula Elegir para devolver un nombre de día / mes personalizado a partir de la fecha

    En situaciones en las que desees obtener un nombre de día en el formato estándar, como el nombre completo (lunes, martes, entre otros) o el nombre corto, puedes usar la función TEXTO como se explica en este ejemplo: Obtener el día de la semana a partir de la fecha en Excel.

    Si deseas devolver el nombre de un día de la semana o un mes en un formato personalizado, usa la función ELEGIR de Excel de la siguiente manera. Para obtener un día de la semana:

    =CHOOSE(WEEKDAY(A2),"Su","Mo","Tu","We","Th","Fr","Sa")

    Para obtener un mes:

    =CHOOSE(MONTH(A2), "Jan","Feb","Mar","Apr","May","Jun","Jul","Aug","Sep","Oct","Nov","Dec")

    Donde A2 es la celda que contiene la fecha original.

    Fórmula Elegir

    Echa un vistazo a: Barras De Datos En Excel. Qué Son Y Cómo Agregarlas

    Pensamientos finales

    Esperamos que este tutorial te haya dado algunas ideas sobre cómo puedes usar la función ELEGIR de Excel para mejorar tus modelos de datos. ¡Gracias por leer y esperamos verte por aquí la próxima semana! Si te ha gustado el tutorial, puedes hacer saber tu opinión en la sección de comentarios. Recuerda que es posible hacer uso de esta función para muchas cosas, solo tienes que adaptar los datos de la fórmula.

    ►TAMBIÉN TE PUEDE INTERESAR◄

    Deja una respuesta

    Tu dirección de correo electrónico no será publicada. Los campos obligatorios están marcados con *

    Subir

    Utilizo cookies propias, de análisis y de terceros para mejorar la experiencia de navegación por mi web. Y en algunos artículos, para mostrarte publicidad relacionada con tus preferencias según el análisis de tu navegación. Pero solo es para seguir ofreciéndote contenido de calidad en el blog de manera totalmente gratuita. Puedes informarte más profundamente sobre qué cookies estoy utilizando y desactivarlas si quieres (algo que agradecería que no hicieras) Quiero saber más